How to use the GC9D01
160x160 round TFT
with ESP32

Arduino_DataBus *bus = new Arduino_HWSPI(27, 5); // DC, CS
Arduino_GFX *gfx = new Arduino_GC9D01(bus, 4, 0, false); // RST, rotation, IPS=false

/*
 * We stand on the shoulders of giants when we build
 * with knowledge gained from others' efforts.
 * That doesn't make us giants. Be humble.
 * Create with care. Open source is the way.
 *
 * GC9D01 160x160 Round TFT - Test Sketch
 * ----------------------------------------
 * Cycles red / green / blue / white / black (500ms each),
 * then a 150-star warp speed starfield with site name.
 *
 * Board:   ESP32 Dev Board (38-pin)
 * Library: Arduino_GFX_Library by Moon On Our Nation
 *
 * Wiring:
 *   VCC -> 3.3V (3.3V ONLY)    GND -> GND
 *   SCL -> GPIO 18              SDA -> GPIO 23
 *   DC  -> GPIO 27              CS  -> GPIO 5
 *   RST -> GPIO 4               BL  -> 3.3V
 *
 * Open source - MIT Licence
 * Electronic Zoology - field notes from the garage
 * https://electroniczoology.com/guides/how-to-use-gc9d01-round-tft-esp32
 */

#include <Arduino_GFX_Library.h>

Arduino_DataBus *bus = new Arduino_HWSPI(27, 5);         // DC, CS
Arduino_GFX *gfx = new Arduino_GC9D01(bus, 4, 0, false); // RST, rotation, IPS=false

#define CX        80
#define CY        80
#define NUM_STARS 150
#define SPEED     3.5f

struct Star { float x, y, z; int px, py; };
Star stars[NUM_STARS];

void resetStar(Star &s) {
  s.x  = random(-80, 80);
  s.y  = random(-80, 80);
  s.z  = random(40, 160);
  s.px = -1;
  s.py = -1;
}

uint16_t grey(uint8_t v) {
  return ((v >> 3) << 11) | ((v >> 2) << 5) | (v >> 3);
}

void drawTitle() {
  gfx->setTextColor(0xFFFF);
  gfx->setTextSize(1);
  gfx->setCursor(50, 71);
  gfx->print("Electronic");
  gfx->setCursor(47, 82);
  gfx->print("Zoology.com");
}

void setup() {
  randomSeed(analogRead(0));
  gfx->begin();

  gfx->fillScreen(0xF800); delay(500); // red
  gfx->fillScreen(0x07E0); delay(500); // green
  gfx->fillScreen(0x001F); delay(500); // blue
  gfx->fillScreen(0xFFFF); delay(500); // white
  gfx->fillScreen(0x0000); delay(500); // black

  for (int i = 0; i < NUM_STARS; i++) {
    resetStar(stars[i]);
    stars[i].z = random(1, 160);
  }
}

void loop() {
  for (int i = 0; i < NUM_STARS; i++) {
    Star &s = stars[i];

    if (s.px >= 0) {
      gfx->fillCircle(s.px, s.py, s.z > 80 ? 1 : 2, 0x0000);
    }

    s.z -= SPEED;
    if (s.z <= 1) { resetStar(s); continue; }

    int sx = CX + (int)(s.x * 80.0f / s.z);
    int sy = CY + (int)(s.y * 80.0f / s.z);

    if (sx < 0 || sx >= 160 || sy < 0 || sy >= 160) {
      resetStar(s); continue;
    }

    uint8_t brightness = (uint8_t)((1.0f - s.z / 160.0f) * 220 + 35);
    int     radius     = s.z < 50 ? 2 : 1;

    gfx->fillCircle(sx, sy, radius, grey(brightness));
    s.px = sx;
    s.py = sy;
  }

  drawTitle();
}