How to set up
TFT_eSPI with ESP32

/*
 * We stand on the shoulders of giants when we build
 * with knowledge gained from others' efforts.
 * That doesn't make us giants. Be humble.
 * Create with care. Open source is the way.
 *
 * TFT_eSPI - Display Test Sketch
 * --------------------------------
 * Cycles red / green / blue (3s each), then a
 * 150-star warp speed starfield with site name.
 * No pin numbers in the sketch - all configured
 * via User_Setup_Select.h.
 *
 * Board:   ESP32 Dev Board (38-pin)
 * Library: TFT_eSPI by Bodmer
 *
 * Wiring (matches Setup46_GC9A01_ESP32.h defaults):
 *   VCC  -> 3.3V or 5V   GND  -> GND
 *   SCL  -> GPIO 18       SDA  -> GPIO 23
 *   DC   -> GPIO 2        CS   -> GPIO 15
 *   RST  -> GPIO 4        MISO -> GPIO 19
 *
 * Open source - MIT Licence
 * Electronic Zoology - field notes from the garage
 * https://electroniczoology.com/guides/how-to-set-up-tft-espi-esp32
 */

#include <TFT_eSPI.h>

TFT_eSPI tft = TFT_eSPI();

#define NUM_STARS 150
#define SPEED     3.5f

struct Star { float x, y, z; int px, py; };
Star stars[NUM_STARS];

int CX, CY;

void resetStar(Star &s) {
  s.x  = random(-CX, CX);
  s.y  = random(-CY, CY);
  s.z  = random(60, 240);
  s.px = -1;
  s.py = -1;
}

uint16_t grey(uint8_t v) {
  return ((v >> 3) << 11) | ((v >> 2) << 5) | (v >> 3);
}

void printCentered(const char* text, int y) {
  int len = strlen(text);
  int size = 1;
  for (int s = 4; s >= 1; s--) {
    if (len * 6 * s <= tft.width() - 4) { size = s; break; }
  }
  tft.setTextSize(size);
  tft.setCursor((tft.width() - len * 6 * size) / 2, y);
  tft.print(text);
}

void drawTitle() {
  tft.setTextColor(TFT_WHITE);
  tft.setTextSize(2);
  printCentered("Electronic", CY - 18);
  printCentered("Zoology",    CY + 2);
}

void setup() {
  tft.init();
  tft.setRotation(0);
  randomSeed(analogRead(0));

  CX = tft.width()  / 2;
  CY = tft.height() / 2;

  tft.fillScreen(TFT_RED);   delay(3000);
  tft.fillScreen(TFT_GREEN); delay(3000);
  tft.fillScreen(TFT_BLUE);  delay(3000);
  tft.fillScreen(TFT_BLACK);

  for (int i = 0; i < NUM_STARS; i++) {
    resetStar(stars[i]);
    stars[i].z = random(1, 240);
  }
}

void loop() {
  for (int i = 0; i < NUM_STARS; i++) {
    Star &s = stars[i];

    if (s.px >= 0) {
      tft.fillCircle(s.px, s.py, s.z > 120 ? 1 : 2, TFT_BLACK);
    }

    s.z -= SPEED;
    if (s.z <= 1) { resetStar(s); continue; }

    int sx = CX + (int)(s.x * (float)CX / s.z);
    int sy = CY + (int)(s.y * (float)CY / s.z);

    if (sx < 0 || sx >= tft.width() || sy < 0 || sy >= tft.height()) {
      resetStar(s); continue;
    }

    uint8_t brightness = (uint8_t)((1.0f - s.z / 240.0f) * 220 + 35);
    int     radius     = s.z < 80 ? 2 : 1;

    tft.fillCircle(sx, sy, radius, grey(brightness));
    s.px = sx;
    s.py = sy;
  }

  drawTitle();
  delay(1);
}