How to build an INA219
battery charger monitor
with ESP32 and OLED

/*
 * We stand on the shoulders of giants when we build
 * with knowledge gained from others' efforts.
 * That doesn't make us giants. Be humble.
 * Create with care. Open source is the way.
 *
 * INA219 Monitor - Scrolling Graph Edition
 * -----------------------------------------
 * Reads voltage and current from an INA219 and displays both
 * numerically and as a scrolling graph on an SSD1306 OLED.
 *
 * Two views rotate automatically every VIEW_ROTATE_MS milliseconds:
 *
 *   Live view:   128 samples at 200ms = ~25 seconds of history
 *                Shows real-time behaviour, ripple, spikes.
 *
 *   Charge view: 128 samples at 60s = ~2 hours of history
 *                Shows the full CC/CV curve as a charge progresses.
 *                Resets on boot. Empty until the first minute passes.
 *
 * Both views share the same numeric top line (live voltage and current).
 * The view label (LIVE / CHARGE) appears top-centre during rotation.
 *
 * Use it to watch a TP4056 charge an 18650, or to watch an ESP32
 * sleep and wake during RTO testing. Same sketch, same wiring.
 *
 * Board:   ESP32 Dev Board (38-pin)
 * Library: Adafruit INA219 by Adafruit
 *          Adafruit SSD1306 + Adafruit GFX by Adafruit
 *
 * Wiring:
 *   INA219 + OLED: SDA -> GPIO 21   SCL -> GPIO 22
 *   Both:          VCC -> 3.3V      GND -> GND
 *   INA219 inline: VIN+ from supply, VIN- to load
 *
 * Open source - MIT Licence
 * Electronic Zoology - field notes from the garage
 * https://electroniczoology.com/guides/how-to-build-ina219-charger-monitor-esp32
 */

#include <Wire.h>
#include <Adafruit_INA219.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH     128
#define SCREEN_HEIGHT    64
#define OLED_RESET       -1
#define OLED_ADDRESS     0x3C    // Change to 0x3D if needed

#define GRAPH_MAX_MA     1200.0f

#define LIVE_SAMPLE_MS   200     // 5 samples/sec, 128 samples = ~25s
#define CHARGE_SAMPLE_MS 60000   // 1 sample/min, 128 samples = ~2hr

#define VIEW_ROTATE_MS   5000    // how long each view shows before flipping

#define GRAPH_Y          10
#define GRAPH_H          (SCREEN_HEIGHT - GRAPH_Y)   // 54px
#define BUF_SIZE         SCREEN_WIDTH                // 128 points

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
Adafruit_INA219   ina219;

// Live buffer
float   liveBuf[BUF_SIZE];
uint8_t liveHead = 0;
bool    liveFull = false;

// Charge buffer
float   chargeBuf[BUF_SIZE];
uint8_t chargeHead = 0;
bool    chargeFull = false;

bool showLive = true;   // which view is currently displayed

void addToLive(float mA) {
  liveBuf[liveHead] = mA;
  liveHead = (liveHead + 1) % BUF_SIZE;
  if (liveHead == 0) liveFull = true;
}

void addToCharge(float mA) {
  chargeBuf[chargeHead] = mA;
  chargeHead = (chargeHead + 1) % BUF_SIZE;
  if (chargeHead == 0) chargeFull = true;
}

void drawGraph(float* buf, uint8_t head, bool full) {
  uint8_t count    = full ? BUF_SIZE : head;
  uint8_t startIdx = full ? head     : 0;

  for (uint8_t i = 0; i < count; i++) {
    uint8_t idx    = (startIdx + i) % BUF_SIZE;
    float   sample = buf[idx];

    if (sample < 0)            sample = 0;
    if (sample > GRAPH_MAX_MA) sample = GRAPH_MAX_MA;

    int barH = (int)((sample / GRAPH_MAX_MA) * (float)(GRAPH_H - 1));
    if (barH < 1 && sample >= 1.0f) barH = 1;

    int x = i;
    int y = GRAPH_Y + (GRAPH_H - 1) - barH;
    display.drawFastVLine(x, y, barH, SSD1306_WHITE);
  }
}

void drawDisplay(float volts, float mA) {
  display.clearDisplay();

  // --- Numeric line ---
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);
  display.print(volts, 2);
  display.print("V");

  // View label centred
  const char* label = showLive ? "LIVE" : "CHARGE";
  int labelW = strlen(label) * 6;
  display.setCursor((SCREEN_WIDTH - labelW) / 2, 0);
  display.print(label);

  // mA right-aligned
  char maBuf[10];
  if (mA < 1.0f) {
    snprintf(maBuf, sizeof(maBuf), "<1mA");
  } else {
    snprintf(maBuf, sizeof(maBuf), "%dmA", (int)mA);
  }
  int maWidth = strlen(maBuf) * 6;
  display.setCursor(SCREEN_WIDTH - maWidth, 0);
  display.print(maBuf);

  // --- Divider ---
  display.drawFastHLine(0, GRAPH_Y - 1, SCREEN_WIDTH, SSD1306_WHITE);

  // --- Graph ---
  if (showLive) {
    drawGraph(liveBuf, liveHead, liveFull);
  } else {
    if (chargeHead == 0 && !chargeFull) {
      // Charge buffer empty - let the reader know
      display.setTextSize(1);
      display.setCursor(10, GRAPH_Y + 18);
      display.print("< 1 min of data");
    } else {
      drawGraph(chargeBuf, chargeHead, chargeFull);
    }
  }

  display.display();
}

void setup() {
  Serial.begin(115200);

  memset(liveBuf,   0, sizeof(liveBuf));
  memset(chargeBuf, 0, sizeof(chargeBuf));

  Wire.begin(21, 22);
  Wire.setClock(400000);

  if (!ina219.begin()) {
    Serial.println("INA219 not found - check wiring");
    while (true) delay(1000);
  }

  if (!display.begin(SSD1306_SWITCHCAPVCC, OLED_ADDRESS)) {
    Serial.println("SSD1306 not found - check wiring and OLED_ADDRESS");
    while (true) delay(1000);
  }

  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);
  display.setTextSize(1);
  display.setCursor(0, 0);
  display.println("INA219 monitor");
  display.println("running...");
  display.display();

  Serial.println("INA219 monitor running");
  delay(1000);
}

void loop() {
  static uint32_t lastLive   = 0;
  static uint32_t lastCharge = 0;
  static uint32_t lastRotate = 0;

  uint32_t now = millis();

  // Live sample
  if (now - lastLive >= LIVE_SAMPLE_MS) {
    lastLive = now;

    float busVoltage = ina219.getBusVoltage_V();
    float current_mA = max(0.0f, ina219.getCurrent_mA());

    Serial.printf("V: %.3f  I: %.1f mA\n", busVoltage, current_mA);

    addToLive(current_mA);

    // Charge sample on its own timer
    if (now - lastCharge >= CHARGE_SAMPLE_MS) {
      lastCharge = now;
      addToCharge(current_mA);
    }

    drawDisplay(busVoltage, current_mA);
  }

  // Rotate view
  if (now - lastRotate >= VIEW_ROTATE_MS) {
    lastRotate = now;
    showLive = !showLive;
  }
}